sigma(average,median)=sqrt(2 * (log(average) - log(median)))
f(x,a,m) = 1 / (x * sigma(a,m) * sqrt(2 * 3.14159)) * exp(- (log(x) - log(m))**2 / (2 * sigma(a,m)**2))
set term pngcairo size 800, 1000 font "mono,9"
set xtics 20000
unset ytics
set grid
set multiplot layout 3, 1
# https://vdb.czso.cz/vdbvo2/faces/cs/index.jsf?page=vystup-objekt&pvo=MZD10&z=T&f=TABULKA&katalog=30852&c=v3~8__RP2022#w=
plot [0:160000] \
f(x,30645,28735) title "základní a nedokončené", \
f(x,33489,31617) title "střední bez maturity", \
f(x,42182,38217) title "střední s maturitou", \
f(x,49709,43575) title "vyšší odborné a bakalářské", \
f(x,64942,52903) title "vysokoškolské"
# https://vdb.czso.cz/vdbvo2/faces/cs/index.jsf?page=vystup-objekt&pvo=MZD09&z=T&f=TABULKA&katalog=30852&str=v265&c=v3~8__RP2022
plot [0:160000] \
f(x, 44211, 42792) title "Zaměstnanci v ozbrojených silách", \
f(x, 95345, 74212) title "Zákonodárci a řídící pracovníci", \
f(x, 62497, 52492) title "Specialisté", \
f(x, 46621, 42827) title "Techničtí a odborní pracovníci", \
f(x, 34998, 32480) title "Úředníci", \
f(x, 30877, 28562) dashtype (9,7) title "Pracovníci ve službách a prodeji", \
f(x, 31456, 30523) dashtype (9,7) title "Kvalifikovaní pracovníci v zemědělství, lesnictví a rybářství", \
f(x, 36435, 35161) dashtype (9,7) title "Řemeslníci a opraváři", \
f(x, 34926, 33473) dashtype (9,7) title "Obsluha strojů a zařízení, montéři", \
f(x, 25198, 23282) dashtype (9,7) title "Pomocní a nekvalifikovaní pracovníci"
# https://vdb.czso.cz/vdbvo2/faces/cs/index.jsf?page=vystup-objekt&pvo=MZD07&z=T&f=TABULKA&katalog=30852&c=v3~8__RP2022#w=
set xlabel "mzdy ->"
plot [0:160000] \
f(x, 54015, 43950) title "Hlavní město Praha", \
f(x, 43536, 38431) title "Středočeský kraj", \
f(x, 39728, 35267) title "Jihočeský kraj", \
f(x, 41436, 37500) title "Plzeňský kraj", \
f(x, 37512, 33679) title "Karlovarský kraj", \
f(x, 40223, 36133) title "Ústecký kraj", \
f(x, 39746, 35643) title "Liberecký kraj", \
f(x, 41187, 36734) dashtype (9,7) title "Královéhradecký kraj", \
f(x, 38866, 35357) dashtype (9,7) title "Pardubický kraj", \
f(x, 39864, 36078) dashtype (9,7) title "Kraj Vysočina", \
f(x, 43071, 37733) dashtype (9,7) title "Jihomoravský kraj", \
f(x, 39079, 35107) dashtype (9,7) title "Olomoucký kraj", \
f(x, 38869, 34968) dashtype (9,7) title "Zlínský kraj", \
f(x, 39631, 35723) dashtype (9,7) title "Moravskoslezský kraj"
unset multiplot